John Malkovichs Toilette — 1 of 1

"John Malkovichs Toilette"

Include Locksmith by Emily Short.

Release along with a website, an interpreter and the source text.

Include German by Team GerX.

A thing is usually privately-named. A room is usually privately-named.

The Bathroom is a room. The printed name is "Badezimmer".

The bathroom door is a female door. It is north of the Bathroom and south of the Bedroom. It is lockable and locked. The printed name of the bathroom door is "Badezimmertür". Understand "Tuer", "Badezimmertuer" and "Tuer des/zum Badezimmer" as the bathroom door. The printed name of the bedroom is "Schlafzimmer".

Before unlocking keylessly the bathroom door:

if the bathroom door is unlocked, say "[Der bathroom door] ist schon unverriegelt." instead;

try turning the latch instead.

Before locking keylessly the bathroom door:

if the bathroom door is locked, say "[Der bathroom door] ist sicher verriegelt." instead;

try turning the latch instead.

Before locking the bathroom door with something:

say "Die Badezimemrtür lässt sich nur verrieglen und nicht mit einem Schlüssel abschließen." instead.

Before unlocking the bathroom door with something:

say "Die Badezimmertür ist verriegelt und lässt sich nicht mit einem Schlüssel öffnen." instead.

The latch is part of the bathroom door. "Ein drehbarer Knopf, der die Tür verriegelt." Understand "Knopf", "Riegel" and "drehbar" as the latch. The description of the bathroom door is "Uninteressant bis auf den Knopf zum Verriegeln der Tür." The printed name of the latch is "drehbar[^] Riegel".

Instead of turning the latch:

if the bathroom door is locked begin;

say "Klick! Du drehst den Knopf und die Tür ist entriegelt[if the door is open] und offen[end if].";

now the bathroom door is unlocked;

otherwise;

say "Klick! Du drehst den Knopf und die Tür ist verriegelt[if the door is open], aber offen; das Schloss wird einschnappen, sobald du die Tür schließt[end if].";

now the bathroom door is locked;

end if.

The little black oval door is a female door. It is west of the Bathroom and east of Oblivion. It is lockable and locked. The printed name is "klein[^] schwarz[^] oval[^] Tür". Understand "klein", "schwarz", "oval" and "Tuer" as the oval door. The description of the oval door is "Sie befindet sich in der Wand des Duschbereichs und lässt sich wer weiß wo öffnen. Du bist dir sicher, dass sie gestern noch nicht da war." The printed name of Oblivion is "Vergessenheit".

The onyx key unlocks the oval door. It is in the Bedroom. The onyx key is male. "Auf dem Boden liegt kantig und schwarz von der Sonne beleuchtet [ein onyx key]." The printed name of the onyx key is "Onyxschlüssel". Understand "Schluessel", "Schluessel aus Onyx" and "Onyxschluessel" as the onyx key.

Test me with " u badezimmertür / schließ ovale tür auf / schließ badezimmertür auf / g / gehe durch badezimmertür / nimm schlüssel / schließ badezimmertür ab / schließ badezimmertür / s / schließ badezimmertür mit dem onyxschlüssel ab / w"